#
精品软件
4月16日
分享一个多ip切换批处理脚本,一键切换本机IP地址
By 壹资源网
4 MIN READ
注：
1、文件保存为.bat运行。
2、如果显示中文乱码，改下文件编码就行，编码：ANSI
1、文件保存为.bat运行。
2、如果显示中文乱码，改下文件编码就行，编码：ANSI
@echo off
REM 定义IP信息二维数组，有多少个ip就定义多少组，下面用的是Tab分隔符
setlocal enabledelayedexpansion
set IPs[1]=DHCP
set IPs[2]=192.168.1.22 255.255.255.0 192.168.1.1
set IPs[3]=192.168.10.22 255.255.255.0 192.168.10.1
set IPs[4]=192.168.31.22 255.255.255.0 192.168.31.1
REM 计算IP个数，最大支持99个ip
set IPsCount=0
for /l %%i in (1,1,99) do (
if defined IPs[%%i] (
set /a IPsCount+=1
)
)
REM 选择要切换的IP组
:input
cls
echo 请选择需要切换的IP组：
for /l %%i in (1,1,%IPsCount%) do (
echo %%i. IP组%%i: !IPs[%%i]!
)
set /p selection=输入组号（1-%IPsCount%）：
if "%selection%" geq "1" if "%selection%" leq "%IPsCount%" (
set ipInfo=!IPs[%selection%]!
) else (
echo 无效的组号，请重新输入！
timeout /t 3 >nul
goto input
)
REM 解析IP信息
for /f "tokens=1-3" %%a in ("%ipInfo%") do (
set addr=%%a
set mask=%%b
set gateway=%%c
)
REM 判断为 DHCP 模式
REM 判断是否为DHCP，是则设置为DHCP模式，否则设置静态IP
if /I "%addr%"=="DHCP" (
netsh interface ip set address name="WLAN" source=dhcp
echo 已切换到 DHCP 模式
) else (
REM 设置静态 IP 地址
netsh interface ip set address name="WLAN" source=static addr=!addr! mask=!mask! gateway=!gateway! gwmetric=0
echo 设置静态 IP 地址完成。
)
REM 刷新DNS缓存
ipconfig /flushdns
echo IP信息设置完成。
pause